set term pngcairo size 1024,1024 font ',10'
# set output 'galaxies.png'
  set output '| ffmpeg -y -r 60 -f image2pipe -i - -vcodec libx264 -profile:v baseline -pix_fmt yuv420p galaxies.mp4'
  set colors classic
  set encoding utf8
  set minussign

  template = 'output_%03d.txt'
  TimeBetSnapshot = 0.01

  unset key
  set ticslevel 0
  set view equal xyz
  set view ,,2

  unset border
# set border 1+2+4+8 + 16+32+64 + 256+512
# set xlabel 'x'
# set ylabel 'y'
# set zlabel 'z'
  unset tics

  r = 150
  set xrange [-r:r]
  set yrange [-r:r]
  set zrange [-r:r]

  n = 1000
  do for [i=0:n] {
    filename = sprintf(template,i)
    print filename
    set title sprintf('t = %4.2f',i*TimeBetSnapshot)

    s = system('read comm npart <'.filename.'; echo $npart')
    eval(s)
    o1 = 0;    o2 = o1+n1; o3 = o2+n2; o4 = o3+n3; o5 = o4+n4; o6 = o5+n5; o7 = o6+n6
    m1 = o2-1; m2 = o3-1;  m3 = o4-1;  m4 = o5-1;  m5 = o6-1;  m6 = o7-1
    m5 = m5>o5?m5:NaN

    splot \
      filename every ::o4::m4 using 4:5:6 w d lt 5 lc rgb '#80009999', \
      filename every ::o3::m3 using 4:5:6 w d lt 3 lc rgb '#800000ff', \
      filename every ::o1::m1 using 4:5:6 w d lt 1 lc rgb '#80ff0000', \
      filename every ::o5::m5 using 4:5:6 w d lt 6 lc rgb '#80ffff00'

  }