program shearsetup
      implicit none

! we use 10x10x1 cubes of our base grid
      integer, parameter :: nx=10, ny=10, nz=1
      integer, parameter :: nbase=1000, npart=nx*ny*nz*nbase
      real,    dimension(3,nbase) :: grid
      real,    dimension(3,npart) :: pos,vel
      real,    dimension(  npart) :: ein
      integer, dimension(  npart) :: id
      double precision, dimension(6) :: masstab
      integer :: i,j,k,l
      real :: gamma,cs,rho0,eps0,p0
      double precision :: mass

! static properties of medium
      gamma = 5./3.
      rho0  = 1.
      mass  = rho0/nbase
      eps0  = 1.

! the base grid has coordinate values 0...1 in all three dimensions
      open(1,file='glass.txt')
      read(1,*) grid
      close(1)

! we scale the coordinates of our initial setup to 10x10x1
      do i=1,nx
        do j=1,ny
          do k=1,nz
            l = (ny*nz*(i-1)+nz*(j-1)+k-1)*nbase
            pos(1,l+1:l+nbase) = grid(1,:) + (i-1)
            pos(2,l+1:l+nbase) = grid(2,:) + (j-1)
            pos(3,l+1:l+nbase) = grid(3,:) + (k-1)
          enddo
        enddo
      enddo
      forall(i=1:npart) id(i)=i
      vel = 0.
      ein = eps0

!set up the moving walls
      do i=1,npart
        if(pos(1,i).lt.0.5) then
          id(i) = 0
          vel(2,i) = -0.1
        endif
        if(pos(1,i).gt.9.5) then
          id(i) = 0
          vel(2,i) = 0.1
        endif
      enddo

! dump coordinates to text file for debugging
      open(1,file='grid.txt')
      write(1,'(i6,6f8.4)') (id(i),pos(:,i),vel(:,i),i=1,npart)
      close(1)

! write the initial conditions file
      masstab = 0.
      masstab(1) = mass
      open(1,file='shear.ic',form='unformatted')
      write(1) 'HEAD',8+256
      write(1) [npart,0,0,0,0,0],masstab, &
        (0,i=1,(256-6*4-6*8)/4) ! pad to 256 bytes
      write(1) 'ID  ',8+4*npart
      write(1) id
      write(1) 'POS ',8+3*4*npart
      write(1) pos
      write(1) 'VEL ',8+3*4*npart
      write(1) vel
      write(1) 'U   ',8+4*npart
      write(1) ein
      close(1)

      end