set term pngcairo size 512,1024
# set output 'jet.png'
  set output '| ffmpeg -y -r 15 -f image2pipe -i - -vcodec libx264 -profile:v baseline -pix_fmt yuv420p jet.mp4'
  set colors classic
  set encoding utf8
  set minussign

  TimeBetSnapshot = 0.1
  nliquid = 218000

  unset key
  set xlabel 'x'
  set ylabel 'y'
  set xrange [0:10]
  set yrange [0:30]
  set xtics 1
  set ytics 1
  set tics front
  set size ratio -1

  set palette model HSV functions 5./6.*gray, 1, 1
  set cblabel 'pressure'
  set cbrange [0:2.5]
  set cbtics 0.5 nomirror
  set colorbox user size graph .05,1 origin graph 1.03,0

  set rmargin 8

  template = 'output_%03d.txt'

  n = 1600
  do for [i=0:n:10] {
    filename=sprintf(template,i)
    print filename
    time = sprintf('t = %4.1f',i*TimeBetSnapshot)
    set title time
    plot \
      filename u             ($2==0?$6:NaN):7         w p pt 7 ps .1 lt 7, \
      filename u        ($2>nliquid?$6:NaN):7:($4*$5) w d            lc palette, \
      filename u ($2>0&&$2<=nliquid?$6:NaN):7:($4*$5) w p pt 7 ps .1 lc palette
  }