program slabsetup
      implicit none

! we use 10x1x1 cubes of our base grid
      integer, parameter :: nbase=1000, npart=10*1*1*nbase
      real,    dimension(3,nbase) :: grid
      real,    dimension(3,npart) :: pos,vel
      real,    dimension(  npart) :: ein
      integer, dimension(  npart) :: id
      double precision, dimension(6) :: masstab
      integer :: i,j,k,l
      real :: gamma,cs,rho0,eps0,p0
      double precision :: mass

! static properties of medium
      gamma = 5./3.
      mass  = 1.
      rho0  = 8000. ! 8000 particles of mass 1 per unit cube
      eps0  = 1.
      p0    = (gamma-1.)*eps0*rho0
      cs    = sqrt(gamma*p0/rho0)

! the base grid has coordinate values 0...1 in all three dimensions
      open(1,file='glass.txt')
      read(1,*) grid
      close(1)

! we scale the coordinates of our initial setup to 10x1x1
      do i=1,10
        l = (i-1)*nbase
        pos(1,l+1:l+nbase) = grid(1,:) + (i-1)
        pos(2,l+1:l+nbase) = grid(2,:)
        pos(3,l+1:l+nbase) = grid(3,:)
      enddo
      id  = 0 ! make all particles boundary particles, so they don't move
      vel = 0.
      ein = eps0

! set up the hot part
      do i=1,npart
        if(pos(1,i).gt.5.) ein(i) = 2.
      enddo

! dump coordinates to text file for debugging
      open(1,file='grid.txt')
      write(1,'(i6,4f8.4)') (id(i),ein(i),pos(:,i),i=1,npart)
      close(1)

! write the initial conditions file
      masstab = 0.
      masstab(1) = mass
      open(1,file='slab.ic',form='unformatted')
      write(1) 'HEAD',8+256
      write(1) [npart,0,0,0,0,0],masstab, &
        (0,i=1,(256-6*4-6*8)/4) ! pad to 256 bytes
      write(1) 'ID  ',8+4*npart
      write(1) id
      write(1) 'POS ',8+3*4*npart
      write(1) pos
      write(1) 'VEL ',8+3*4*npart
      write(1) vel
      write(1) 'U   ',8+4*npart
      write(1) ein
      close(1)


      end