set term post enh color solid
  set output 'plot.ps'
  set encoding iso_8859_1
  set colors classic

  gamma = 5./3.
  rho0  = 1000.
  eps0  = 1.
  p0    = (gamma-1.)*eps0*rho0
  cs    = sqrt(gamma*p0/rho0)

  set style line  1 lt 1 lc rgb '#ffcccc'
  set style line  2 lt 2 lc rgb '#ccffcc'
  set style line  3 lt 3 lc rgb '#ccccff'
  set style line  4 lt 7 lc rgb '#cccccc'

  set style line 11 lt 1 lc rgb '#ff0000'
  set style line 12 lt 2 lc rgb '#00ff00'
  set style line 13 lt 3 lc rgb '#0000ff'
  set style line 14 lt 7 lc rgb '#000000'

  set yrange [-0.02:0.02]
  set samples 2
  set key top left reverse Left

  t0 = 0.    # initial conditions
  t1 = 5.    # corresponds to snapshot number 50 if TimeBetSnapshot = 0.1
  dt = t1-t0
  dx = cs*dt
  x0 = 10.5

  set arrow from x0,   graph 0 to x0,   graph 1 nohead ls  4
  set arrow from x0+dx,graph 0 to x0+dx,graph 1 nohead ls 14
  set label sprintf('t = %3.1f',t0) at x0,   graph 0.9 right offset -1,0 textcolor ls  4
  set label sprintf('t = %3.1f',t1) at x0+dx,graph 0.9 left  offset  1,0 textcolor ls 14
  plot \
    NaN w l lt 11 title 'eps/eps0 - 1', \
    NaN w l lt 12 title 'rho/rho0 - 1', \
    NaN w l lt 13 title 'v', \
    'output_000.txt' u 6:($5/eps0-1.) w d ls  1 notitle, \
    'output_000.txt' u 6:($4/rho0-1.) w d ls  2 notitle, \
    'output_000.txt' u 6:9            w d ls  3 notitle, \
    'output_050.txt' u 6:($5/eps0-1.) w d ls 11 notitle, \
    'output_050.txt' u 6:($4/rho0-1.) w d ls 12 notitle, \
    'output_050.txt' u 6:9            w d ls 13 notitle