program slabsetup
      implicit none

! we use 10 cubes of the base grid for the low-density region,
! and 8*10 reduced cubes of the base grid for the high-density part
      integer, parameter :: nbase=1000,npart=10*nbase+80*nbase
      real,    dimension(3,nbase) :: grid
      real,    dimension(3,npart) :: pos,vel
      real,    dimension(  npart) :: ein
      integer, dimension(  npart) :: id
      double precision :: masstab(6)
      integer :: i,j,k,l

! the base grid has coordinate values 0...1 in all three dimensions
      open(1,file='glass.txt')
      read(1,*) grid
      close(1)

! set up the low-density part
      do i=1,10
        l = (i-1)*nbase
        pos(1,l+1:l+nbase) = grid(1,:) + i-1
        pos(2,l+1:l+nbase) = grid(2,:)
        pos(3,l+1:l+nbase) = grid(3,:)
      enddo

! set up the high-density part
      do i=1,20
        do j=1,2
          do k=1,2
            l = (10+4*(i-1)+2*(j-1)+k-1)*nbase
            pos(1,l+1:l+nbase) = 0.5*grid(1,:) + 0.5*(20+i-1)
            pos(2,l+1:l+nbase) = 0.5*grid(2,:) + 0.5*(j-1)
            pos(3,l+1:l+nbase) = 0.5*grid(3,:) + 0.5*(k-1)
          enddo
        enddo
      enddo

! dump coordinates to text file for debugging
      open(1,file='grid.txt')
      write(1,'(i6,3f8.4)') (i,pos(:,i),i=1,npart)
      close(1)

! write the initial conditions file
      masstab = [1.,0.,0.,0.,0.,0.]
      vel = 0.
      ein = 1.
      id = [(i,i=1,npart)]
      open(1,file='slab.ic',form='unformatted')
      write(1) 'HEAD',8+256
      write(1) [npart,0,0,0,0,0],masstab, &
        (0,i=1,(256-6*4-6*8)/4) ! pad to 256 bytes
      write(1) 'ID  ',8+4*npart
      write(1) id
      write(1) 'POS ',8+3*4*npart
      write(1) pos
      write(1) 'VEL ',8+3*4*npart
      write(1) vel
      write(1) 'U   ',8+4*npart
      write(1) ein
      close(1)

      end